#!/bin/csh

set date=`/usr/bin/date +%Y%m%d`
set logs = /tmp/nn-$$

cat >$logs
less <$logs 

while (1)
  echo ""
  echo -n "Opts: [c]ancel, [p]gpcheck, [l]ist, [e]dit, [m]odcheck, [s]pamcheck, [q]uit: "
  set ans = "`head -1 </dev/tty`"
  switch ( $ans ) 
    case c*:
      echo ""
      echo -n "Cancel type: [p]ersonal, [m]oderator, [f]orgery, [n]one: "
      set ans2 = "`head -1 </dev/tty`"
      switch ( $ans2 )
    	case p*:
	  ~/progs/bin/cancel.pl -t'personal' < $logs
	  echo "Cancel issued."
	  echo ""
	  breaksw
    	case m*:
	  ~/progs/bin/cancel.pl -t'moderator' < $logs
	  cp $logs ~tskirvin/news/cancel/mod-$date-$$
	  echo "Cancel issued."
	  echo ""
	  breaksw
    	case f*:
	  ~/progs/bin/cancel.pl -t'forgery' < $logs
	  cp $logs ~tskirvin/news/cancel/forge-$date-$$
	  echo "Cancel issued."
	  echo ""
	  breaksw
    	case n*:
	default:
	  echo ""
	  breaksw
      endsw
      breaksw

    case l*:
	less <$logs
	breaksw
    case m*:
  	~tskirvin/progs/bin/pmcheck < $logs
	breaksw
    case p*:
	~tskirvin/progs/bin/pmcheck-personal < $logs
	breaksw
    case e*:
	/usr/local/bin/vim $logs </dev/tty
	breaksw
    case q*:
 	echo ""
      	break
    case s*:
	/usr/local/bin/spamassassin -P < $logs | less
	echo ""
	break
    default: 
	echo "Aborted."
	break
  endsw
end

rm -rf $logs